Add dyn_maps package

2 files changed, 249 insertions, 0 deletions

diff --git a/src/dyn_maps.adb b/src/dyn_maps.adb
new file mode 100644
index 000000000..72a195c62
--- /dev/null
+++ b/src/dyn_maps.adb
@@ -0,0 +1,147 @@
+--  Type interning - set of unique objects.
+--  Copyright (C) 2019 Tristan Gingold
+--
+--  GHDL is free software; you can redistribute it and/or modify it under
+--  the terms of the GNU General Public License as published by the Free
+--  Software Foundation; either version 2, or (at your option) any later
+--  version.
+--
+--  GHDL is distributed in the hope that it will be useful, but WITHOUT ANY
+--  WARRANTY; without even the implied warranty of MERCHANTABILITY or
+--  FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
+--  for more details.
+--
+--  You should have received a copy of the GNU General Public License
+--  along with GHDL; see the file COPYING.  If not, write to the Free
+--  Software Foundation, 59 Temple Place - Suite 330, Boston, MA
+--  02111-1307, USA.
+
+with Ada.Unchecked_Deallocation;
+
+package body Dyn_Maps is
+   procedure Deallocate is new Ada.Unchecked_Deallocation
+     (Hash_Array, Hash_Array_Acc);
+
+   procedure Init (Inst : out Instance) is
+   begin
+      Inst.Size := Initial_Size;
+      Inst.Hash_Table := new Hash_Array'(0 .. Initial_Size - 1 => No_Index);
+      Wrapper_Tables.Init (Inst.Els, 128);
+      pragma Assert (Wrapper_Tables.Last (Inst.Els) = No_Index);
+   end Init;
+
+   procedure Free (Inst : in out Instance) is
+   begin
+      Deallocate (Inst.Hash_Table);
+      Inst.Size := 0;
+      Wrapper_Tables.Free (Inst.Els);
+   end Free;
+
+   --  Expand the hash table (double the size).
+   procedure Expand (Inst : in out Instance)
+   is
+      Old_Hash_Table : Hash_Array_Acc;
+      Idx : Index_Type;
+   begin
+      Old_Hash_Table := Inst.Hash_Table;
+      Inst.Size := Inst.Size * 2;
+      Inst.Hash_Table := new Hash_Array'(0 .. Inst.Size - 1 => No_Index);
+
+      --  Rehash.
+      for I in Old_Hash_Table'Range loop
+         Idx := Old_Hash_Table (I);
+         while Idx /= No_Index loop
+            --  Note: collisions are put in reverse order.
+            declare
+               Ent : Element_Wrapper renames Inst.Els.Table (Idx);
+               Hash_Index : constant Hash_Value_Type :=
+                 Ent.Hash and (Inst.Size - 1);
+               Next_Idx : constant Index_Type := Ent.Next;
+            begin
+               Ent.Next := Inst.Hash_Table (Hash_Index);
+               Inst.Hash_Table (Hash_Index) := Idx;
+               Idx := Next_Idx;
+            end;
+         end loop;
+      end loop;
+
+      Deallocate (Old_Hash_Table);
+   end Expand;
+
+   procedure Get_Index
+     (Inst : in out Instance; Params : Params_Type; Idx : out Index_Type)
+   is
+      Hash_Value : Hash_Value_Type;
+      Hash_Index : Hash_Value_Type;
+   begin
+      --  Check if the package was initialized.
+      pragma Assert (Inst.Hash_Table /= null);
+
+      Hash_Value := Hash (Params);
+      Hash_Index := Hash_Value and (Inst.Size - 1);
+
+      Idx := Inst.Hash_Table (Hash_Index);
+      while Idx /= No_Index loop
+         declare
+            E : Element_Wrapper renames Inst.Els.Table (Idx);
+         begin
+            if E.Hash = Hash_Value and then Equal (E.Obj, Params) then
+               return;
+            end if;
+            Idx := E.Next;
+         end;
+      end loop;
+
+      --  Maybe expand the table.
+      if Hash_Value_Type (Wrapper_Tables.Last (Inst.Els)) > 2 * Inst.Size then
+         Expand (Inst);
+
+         --  Recompute hash index.
+         Hash_Index := Hash_Value and (Inst.Size - 1);
+      end if;
+
+      declare
+         Res : Object_Type;
+         Val : Value_Type;
+      begin
+         Res := Build (Params);
+         Val := Build_Value (Res);
+
+         --  Insert.
+         Wrapper_Tables.Append (Inst.Els,
+                                (Hash => Hash_Value,
+                                 Next => Inst.Hash_Table (Hash_Index),
+                                 Obj => Res,
+                                 Val => Val));
+         Inst.Hash_Table (Hash_Index) := Wrapper_Tables.Last (Inst.Els);
+      end;
+
+      Idx := Wrapper_Tables.Last (Inst.Els);
+   end Get_Index;
+
+   function Last_Index (Inst : Instance) return Index_Type is
+   begin
+      return Wrapper_Tables.Last (Inst.Els);
+   end Last_Index;
+
+   function Get_By_Index (Inst : Instance; Index : Index_Type)
+                         return Object_Type is
+   begin
+      pragma Assert (Index <= Wrapper_Tables.Last (Inst.Els));
+      return Inst.Els.Table (Index).Obj;
+   end Get_By_Index;
+
+   function Get_Value (Inst : Instance; Index : Index_Type)
+                       return Value_Type is
+   begin
+      pragma Assert (Index <= Wrapper_Tables.Last (Inst.Els));
+      return Inst.Els.Table (Index).Val;
+   end Get_Value;
+
+   procedure Set_Value
+     (Inst : in out Instance; Index : Index_Type; Val : Value_Type) is
+   begin
+      pragma Assert (Index <= Wrapper_Tables.Last (Inst.Els));
+      Inst.Els.Table (Index).Val := Val;
+   end Set_Value;
+end Dyn_Maps;
diff --git a/src/dyn_maps.ads b/src/dyn_maps.ads
new file mode 100644
index 000000000..2fb7485db
--- /dev/null
+++ b/src/dyn_maps.ads
@@ -0,0 +1,102 @@
+--  Maps - association of unique object with a value.
+--  Copyright (C) 2019-2020 Tristan Gingold
+--
+--  GHDL is free software; you can redistribute it and/or modify it under
+--  the terms of the GNU General Public License as published by the Free
+--  Software Foundation; either version 2, or (at your option) any later
+--  version.
+--
+--  GHDL is distributed in the hope that it will be useful, but WITHOUT ANY
+--  WARRANTY; without even the implied warranty of MERCHANTABILITY or
+--  FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
+--  for more details.
+--
+--  You should have received a copy of the GNU General Public License
+--  along with GHDL; see the file COPYING.  If not, write to the Free
+--  Software Foundation, 59 Temple Place - Suite 330, Boston, MA
+--  02111-1307, USA.
+
+with Types; use Types;
+with Hash; use Hash;
+with Dyn_Tables;
+
+--  This generic package provides a factory to build unique objects.
+--  Get will return an existing object or create a new one.
+generic
+   --  Parameters of the object to be created.
+   type Params_Type (<>) is private;
+
+   --  Object to be built and stored.
+   type Object_Type is private;
+
+   --  Value associated to the object.  Could be modified but not used
+   --  for comparision.
+   type Value_Type is private;
+
+   --  Reduce PARAMS to a small value.
+   --  The required property is: Hash(P1) /= Hash(P2) => P1 /= P2.
+   with function Hash (Params : Params_Type) return Hash_Value_Type;
+
+   --  Create an object from PARAMS.
+   with function Build (Params : Params_Type) return Object_Type;
+
+   --  Initial value of the object.  Called when an object is created.
+   with function Build_Value (Obj : Object_Type) return Value_Type;
+
+   --  Return True iff OBJ is the object corresponding to PARAMS.
+   with function Equal (Obj : Object_Type; Params : Params_Type)
+                       return Boolean;
+package Dyn_Maps is
+   type Instance is limited private;
+
+   --  Initialize.  Required before any other operation.
+   procedure Init (Inst : out Instance);
+
+   procedure Free (Inst : in out Instance);
+
+   type Index_Type is new Uns32;
+   No_Index : constant Index_Type := 0;
+   First_Index : constant Index_Type := 1;
+
+   --  If there is already an existing object for PARAMS, return its index.
+   --  Otherwise create it.
+   --  The index is doesn't change over the lifetime of the map.
+   procedure Get_Index
+     (Inst : in out Instance; Params : Params_Type; Idx : out Index_Type);
+
+   --  Get the number of elements in the table.
+   function Last_Index (Inst : Instance) return Index_Type;
+
+   --  Get an element by index.  The index has no real meaning, but the
+   --  current implementation allocates index incrementally.
+   function Get_By_Index (Inst : Instance; Index : Index_Type)
+                          return Object_Type;
+
+   --  Get/Set the value.
+   function Get_Value (Inst : Instance; Index : Index_Type) return Value_Type;
+   procedure Set_Value
+     (Inst : in out Instance; Index : Index_Type; Val : Value_Type);
+private
+   type Element_Wrapper is record
+      Hash : Hash_Value_Type;
+      Next : Index_Type := No_Index;
+      Obj  : Object_Type;
+      Val  : Value_Type;
+   end record;
+
+   package Wrapper_Tables is new Dyn_Tables
+     (Table_Index_Type => Index_Type,
+      Table_Component_Type => Element_Wrapper,
+      Table_Low_Bound => No_Index + 1);
+
+   type Hash_Array is array (Hash_Value_Type range <>) of Index_Type;
+   type Hash_Array_Acc is access Hash_Array;
+
+   Initial_Size : constant Hash_Value_Type := 1024;
+
+   type Instance is record
+      Els : Wrapper_Tables.Instance;
+      Size : Hash_Value_Type;
+      Hash_Table : Hash_Array_Acc;
+   end record;
+end Dyn_Maps;