aboutsummaryrefslogtreecommitdiffstats
path: root/ice40
diff options
context:
space:
mode:
Diffstat (limited to 'ice40')
-rw-r--r--ice40/CMakeLists.txt90
-rw-r--r--ice40/arch.cc4
-rw-r--r--ice40/arch.h2
-rw-r--r--ice40/family.cmake166
-rw-r--r--ice40/resource/chipdb.rc10
5 files changed, 145 insertions, 127 deletions
diff --git a/ice40/CMakeLists.txt b/ice40/CMakeLists.txt
new file mode 100644
index 00000000..a003443c
--- /dev/null
+++ b/ice40/CMakeLists.txt
@@ -0,0 +1,90 @@
+cmake_minimum_required(VERSION 3.3)
+project(chipdb-ice40 NONE)
+
+set(ALL_ICE40_DEVICES 384 1k 5k u4k 8k)
+set(ICE40_DEVICES ${ALL_ICE40_DEVICES} CACHE STRING
+ "Include support for these iCE40 devices (available: ${ALL_ICE40_DEVICES})")
+message(STATUS "Enabled iCE40 devices: ${ICE40_DEVICES}")
+
+if(DEFINED ICE40_CHIPDB)
+ add_custom_target(chipdb-ice40-bbas ALL)
+else()
+ find_package(PythonInterp 3.5 REQUIRED)
+
+ # shared among all families
+ set(SERIALIZE_CHIPDBS TRUE CACHE BOOL
+ "Serialize device data preprocessing to minimize memory use")
+
+ set(icestorm_default_install_prefix ${CMAKE_INSTALL_PREFIX})
+ # for compatibility with old build scripts
+ if(DEFINED ICEBOX_ROOT)
+ message(WARNING "-DICEBOX_ROOT= is deprecated, use -DICESTORM_INSTALL_PREFIX=${ICEBOX_ROOT} instead")
+ get_filename_component(dir ${ICEBOX_ROOT} DIRECTORY)
+ get_filename_component(dir ${dir} DIRECTORY)
+ set(icestorm_default_install_prefix ${dir})
+ endif()
+ set(ICESTORM_INSTALL_PREFIX ${icestorm_default_install_prefix} CACHE STRING
+ "IceStorm install prefix")
+ message(STATUS "IceStorm install prefix: ${ICESTORM_INSTALL_PREFIX}")
+
+ if(NOT DEFINED ICEBOX_DATADIR)
+ set(ICEBOX_DATADIR ${ICESTORM_INSTALL_PREFIX}/share/icebox)
+ endif()
+ message(STATUS "icebox data directory: ${ICEBOX_DATADIR}")
+
+ set(all_device_bbas)
+ file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/chipdb)
+ foreach(device ${ICE40_DEVICES})
+ if(NOT device IN_LIST ALL_ICE40_DEVICES)
+ message(FATAL_ERROR "Device ${device} is not a supported iCE40 device")
+ endif()
+
+ if(device STREQUAL "5k")
+ set(timing_opts
+ --slow ${ICEBOX_DATADIR}/timings_up5k.txt)
+ elseif(device STREQUAL "u4k")
+ set(timing_opts
+ --slow ${ICEBOX_DATADIR}/timings_u4k.txt)
+ elseif(device STREQUAL "384")
+ set(timing_opts
+ --slow ${ICEBOX_DATADIR}/timings_lp384.txt)
+ else()
+ set(timing_opts
+ --fast ${ICEBOX_DATADIR}/timings_hx${device}.txt
+ --slow ${ICEBOX_DATADIR}/timings_lp${device}.txt)
+ endif()
+
+ set(device_bba chipdb/chipdb-${device}.bba)
+ add_custom_command(
+ OUTPUT ${device_bba}
+ COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/chipdb.py
+ -p ${CMAKE_CURRENT_SOURCE_DIR}/constids.inc
+ -g ${CMAKE_CURRENT_SOURCE_DIR}/gfx.h
+ ${timing_opts}
+ ${ICEBOX_DATADIR}/chipdb-${device}.txt
+ > ${device_bba}.new
+ # atomically update
+ COMMAND ${CMAKE_COMMAND} -E rename ${device_bba}.new ${device_bba}
+ DEPENDS
+ ${CMAKE_CURRENT_SOURCE_DIR}/chipdb.py
+ ${CMAKE_CURRENT_SOURCE_DIR}/constids.inc
+ ${CMAKE_CURRENT_SOURCE_DIR}/gfx.h
+ ${PREVIOUS_CHIPDB_TARGET}
+ VERBATIM)
+ list(APPEND all_device_bbas ${device_bba})
+ if(SERIALIZE_CHIPDBS)
+ set(PREVIOUS_CHIPDB_TARGET ${CMAKE_CURRENT_BINARY_DIR}/${device_bba})
+ endif()
+ endforeach()
+
+ add_custom_target(chipdb-ice40-bbas ALL DEPENDS ${all_device_bbas})
+
+ get_directory_property(has_parent PARENT_DIRECTORY)
+ if(has_parent)
+ set(ICE40_CHIPDB ${CMAKE_CURRENT_BINARY_DIR}/chipdb PARENT_SCOPE)
+ # serialize chipdb build across multiple architectures
+ set(PREVIOUS_CHIPDB_TARGET chipdb-ice40-bbas PARENT_SCOPE)
+ else()
+ message(STATUS "Build nextpnr with -DICE40_CHIPDB=${CMAKE_CURRENT_BINARY_DIR}")
+ endif()
+endif()
diff --git a/ice40/arch.cc b/ice40/arch.cc
index 645e93cb..545066ce 100644
--- a/ice40/arch.cc
+++ b/ice40/arch.cc
@@ -46,7 +46,7 @@ void IdString::initialize_arch(const BaseCtx *ctx)
static const ChipInfoPOD *get_chip_info(const RelPtr<ChipInfoPOD> *ptr) { return ptr->get(); }
-#if defined(_MSC_VER)
+#if defined(WIN32)
void load_chipdb();
#endif
@@ -82,7 +82,7 @@ void load_chipdb()
#endif
Arch::Arch(ArchArgs args) : args(args)
{
-#if defined(_MSC_VER) || defined(EXTERNAL_CHIPDB_ROOT)
+#if defined(WIN32) || defined(EXTERNAL_CHIPDB_ROOT)
load_chipdb();
#endif
diff --git a/ice40/arch.h b/ice40/arch.h
index f2f9069a..356891ce 100644
--- a/ice40/arch.h
+++ b/ice40/arch.h
@@ -244,7 +244,7 @@ NPNR_PACKED_STRUCT(struct ChipInfoPOD {
RelPtr<RelPtr<char>> tile_wire_names;
});
-#if defined(_MSC_VER) || defined(EXTERNAL_CHIPDB_ROOT)
+#if defined(WIN32) || defined(EXTERNAL_CHIPDB_ROOT)
extern const char *chipdb_blob_384;
extern const char *chipdb_blob_1k;
extern const char *chipdb_blob_5k;
diff --git a/ice40/family.cmake b/ice40/family.cmake
index 0252e36a..5921fa3c 100644
--- a/ice40/family.cmake
+++ b/ice40/family.cmake
@@ -1,123 +1,51 @@
-if (NOT EXTERNAL_CHIPDB)
- if (ICE40_HX1K_ONLY)
- set(devices 1k)
- foreach (target ${family_targets})
- target_compile_definitions(${target} PRIVATE ICE40_HX1K_ONLY=1)
- endforeach (target)
- else()
- set(devices 384 1k 5k u4k 8k)
- endif()
-
- set(DB_PY ${CMAKE_CURRENT_SOURCE_DIR}/ice40/chipdb.py)
+add_subdirectory(${family})
+message(STATUS "Using iCE40 chipdb: ${ICE40_CHIPDB}")
- set(ICEBOX_ROOT ${CMAKE_INSTALL_PREFIX}/share/icebox CACHE STRING "icebox location root")
- file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/ice40/chipdbs/)
- add_library(ice40_chipdb OBJECT ${CMAKE_CURRENT_BINARY_DIR}/ice40/chipdbs/)
- target_compile_definitions(ice40_chipdb PRIVATE NEXTPNR_NAMESPACE=nextpnr_${family})
- target_include_directories(ice40_chipdb PRIVATE ${family}/)
+set(chipdb_sources)
+set(chipdb_binaries)
+file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/${family}/chipdb)
+foreach(device ${ICE40_DEVICES})
+ set(chipdb_bba ${ICE40_CHIPDB}/chipdb-${device}.bba)
+ set(chipdb_bin ${family}/chipdb/chipdb-${device}.bin)
+ set(chipdb_cc ${family}/chipdb/chipdb-${device}.cc)
+ if(BBASM_MODE STREQUAL "binary")
+ add_custom_command(
+ OUTPUT ${chipdb_bin}
+ COMMAND bbasm ${BBASM_ENDIAN_FLAG} ${chipdb_bba} ${chipdb_bin}
+ DEPENDS bbasm chipdb-${family}-bbas ${chipdb_bba})
+ list(APPEND chipdb_binaries ${chipdb_bin})
+ elseif(BBASM_MODE STREQUAL "embed")
+ add_custom_command(
+ OUTPUT ${chipdb_cc} ${chipdb_bin}
+ COMMAND bbasm ${BBASM_ENDIAN_FLAG} --e ${chipdb_bba} ${chipdb_cc} ${chipdb_bin}
+ DEPENDS bbasm chipdb-${family}-bbas ${chipdb_bba})
+ list(APPEND chipdb_sources ${chipdb_cc})
+ list(APPEND chipdb_binaries ${chipdb_bin})
+ elseif(BBASM_MODE STREQUAL "string")
+ add_custom_command(
+ OUTPUT ${chipdb_cc}
+ COMMAND bbasm ${BBASM_ENDIAN_FLAG} --c ${chipdb_bba} ${chipdb_cc}
+ DEPENDS bbasm chipdb-${family}-bbas ${chipdb_bba})
+ list(APPEND chipdb_sources ${chipdb_cc})
+ endif()
+endforeach()
+if(WIN32)
+ list(APPEND chipdb_sources
+ ${CMAKE_CURRENT_SOURCE_DIR}/${family}/resource/embed.cc
+ ${CMAKE_CURRENT_SOURCE_DIR}/${family}/resource/chipdb.rc)
+endif()
- if (MSVC)
- target_sources(ice40_chipdb PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/ice40/resource/embed.cc)
- set_source_files_properties(${CMAKE_CURRENT_SOURCE_DIR}/ice40/resources/chipdb.rc PROPERTIES LANGUAGE RC)
- set(PREV_DEV_CC_BBA_DB)
- foreach (dev ${devices})
- if (dev STREQUAL "5k")
- set(OPT_FAST "")
- set(OPT_SLOW --slow ${ICEBOX_ROOT}/timings_up5k.txt)
- elseif (dev STREQUAL "u4k")
- set(OPT_FAST "")
- set(OPT_SLOW --slow ${ICEBOX_ROOT}/timings_u4k.txt)
- elseif (dev STREQUAL "384")
- set(OPT_FAST "")
- set(OPT_SLOW --slow ${ICEBOX_ROOT}/timings_lp384.txt)
- else()
- set(OPT_FAST --fast ${ICEBOX_ROOT}/timings_hx${dev}.txt)
- set(OPT_SLOW --slow ${ICEBOX_ROOT}/timings_lp${dev}.txt)
- endif()
- set(DEV_TXT_DB ${ICEBOX_ROOT}/chipdb-${dev}.txt)
- set(DEV_CC_BBA_DB ${CMAKE_CURRENT_BINARY_DIR}/ice40/chipdbs/chipdb-${dev}.bba)
- set(DEV_CC_DB ${CMAKE_CURRENT_BINARY_DIR}/ice40/chipdbs/chipdb-${dev}.bin)
- set(DEV_CONSTIDS_INC ${CMAKE_CURRENT_SOURCE_DIR}/ice40/constids.inc)
- set(DEV_GFXH ${CMAKE_CURRENT_SOURCE_DIR}/ice40/gfx.h)
+add_custom_target(chipdb-${family}-bins DEPENDS ${chipdb_sources} ${chipdb_binaries})
- if(PREGENERATED_BBA_PATH)
- add_custom_command(OUTPUT ${DEV_CC_DB}
- COMMAND bbasm ${BBASM_ENDIAN_FLAG} ${PREGENERATED_BBA_PATH}/chipdb-${dev}.bba ${DEV_CC_DB}
- )
- else()
- add_custom_command(OUTPUT ${DEV_CC_BBA_DB}
- COMMAND ${PYTHON_EXECUTABLE} ${DB_PY} -p ${DEV_CONSTIDS_INC} -g ${DEV_GFXH} ${OPT_FAST} ${OPT_SLOW} ${DEV_TXT_DB} > ${DEV_CC_BBA_DB}
- DEPENDS ${DEV_CONSTIDS_INC} ${DEV_GFXH} ${DEV_TXT_DB} ${DB_PY} ${PREV_DEV_CC_BBA_DB}
- )
- add_custom_command(OUTPUT ${DEV_CC_DB}
- COMMAND bbasm ${BBASM_ENDIAN_FLAG} ${DEV_CC_BBA_DB} ${DEV_CC_DB}
- DEPENDS bbasm ${DEV_CC_BBA_DB}
- )
- endif()
- if (SERIALIZE_CHIPDB)
- set(PREV_DEV_CC_BBA_DB ${DEV_CC_BBA_DB})
- endif()
- target_sources(ice40_chipdb PRIVATE ${DEV_CC_DB})
- set_source_files_properties(${DEV_CC_DB} PROPERTIES HEADER_FILE_ONLY TRUE)
- foreach (target ${family_targets})
- target_sources(${target} PRIVATE $<TARGET_OBJECTS:ice40_chipdb> ${CMAKE_CURRENT_SOURCE_DIR}/ice40/resource/chipdb.rc)
- endforeach()
- endforeach()
- else()
- target_compile_options(ice40_chipdb PRIVATE -g0 -O0 -w)
- set(PREV_DEV_CC_BBA_DB)
- foreach (dev ${devices})
- if (dev STREQUAL "5k")
- set(OPT_FAST "")
- set(OPT_SLOW --slow ${ICEBOX_ROOT}/timings_up5k.txt)
- elseif (dev STREQUAL "u4k")
- set(OPT_FAST "")
- set(OPT_SLOW --slow ${ICEBOX_ROOT}/timings_u4k.txt)
- elseif (dev STREQUAL "384")
- set(OPT_FAST "")
- set(OPT_SLOW --slow ${ICEBOX_ROOT}/timings_lp384.txt)
- else()
- set(OPT_FAST --fast ${ICEBOX_ROOT}/timings_hx${dev}.txt)
- set(OPT_SLOW --slow ${ICEBOX_ROOT}/timings_lp${dev}.txt)
- endif()
- set(DEV_TXT_DB ${ICEBOX_ROOT}/chipdb-${dev}.txt)
- set(DEV_CC_BBA_DB ${CMAKE_CURRENT_BINARY_DIR}/ice40/chipdbs/chipdb-${dev}.bba)
- set(DEV_CC_DB ${CMAKE_CURRENT_BINARY_DIR}/ice40/chipdbs/chipdb-${dev}.cc)
- set(DEV_BIN_DB ${CMAKE_CURRENT_BINARY_DIR}/ice40/chipdbs/chipdb-${dev}.bin)
- set(DEV_CONSTIDS_INC ${CMAKE_CURRENT_SOURCE_DIR}/ice40/constids.inc)
- set(DEV_GFXH ${CMAKE_CURRENT_SOURCE_DIR}/ice40/gfx.h)
- if(PREGENERATED_BBA_PATH)
- add_custom_command(OUTPUT ${DEV_CC_DB}
- COMMAND bbasm --c ${BBASM_ENDIAN_FLAG} ${PREGENERATED_BBA_PATH}/chipdb-${dev}.bba ${DEV_CC_DB}.new
- COMMAND mv ${DEV_CC_DB}.new ${DEV_CC_DB}
- )
- else()
- add_custom_command(OUTPUT ${DEV_CC_BBA_DB}
- COMMAND ${PYTHON_EXECUTABLE} ${DB_PY} -p ${DEV_CONSTIDS_INC} -g ${DEV_GFXH} ${OPT_FAST} ${OPT_SLOW} ${DEV_TXT_DB} > ${DEV_CC_BBA_DB}.new
- COMMAND mv ${DEV_CC_BBA_DB}.new ${DEV_CC_BBA_DB}
- DEPENDS ${DEV_CONSTIDS_INC} ${DEV_GFXH} ${DEV_TXT_DB} ${DB_PY} ${PREV_DEV_CC_BBA_DB}
- )
- if(USE_C_EMBED)
- add_custom_command(OUTPUT ${DEV_CC_DB}
- COMMAND bbasm --e ${BBASM_ENDIAN_FLAG} ${DEV_CC_BBA_DB} ${DEV_CC_DB}.new ${DEV_BIN_DB}
- COMMAND mv ${DEV_CC_DB}.new ${DEV_CC_DB}
- DEPENDS bbasm ${DEV_CC_BBA_DB}
- )
- else()
- add_custom_command(OUTPUT ${DEV_CC_DB}
- COMMAND bbasm --c ${BBASM_ENDIAN_FLAG} ${DEV_CC_BBA_DB} ${DEV_CC_DB}.new
- COMMAND mv ${DEV_CC_DB}.new ${DEV_CC_DB}
- DEPENDS bbasm ${DEV_CC_BBA_DB}
- )
- endif()
- endif()
- if (SERIALIZE_CHIPDB)
- set(PREV_DEV_CC_BBA_DB ${DEV_CC_BBA_DB})
- endif()
- target_sources(ice40_chipdb PRIVATE ${DEV_CC_DB})
- foreach (target ${family_targets})
- target_sources(${target} PRIVATE $<TARGET_OBJECTS:ice40_chipdb>)
- endforeach()
- endforeach()
- endif()
+add_library(chipdb-${family} OBJECT ${ICE40_CHIPDB} ${chipdb_sources})
+add_dependencies(chipdb-${family} chipdb-${family}-bins)
+target_compile_options(chipdb-${family} PRIVATE -g0 -O0 -w)
+target_compile_definitions(chipdb-${family} PRIVATE NEXTPNR_NAMESPACE=nextpnr_${family})
+target_include_directories(chipdb-${family} PRIVATE ${family})
+if(ICE40_DEVICES STREQUAL "1k")
+ target_compile_definitions(chipdb-${family} PUBLIC ICE40_HX1K_ONLY=1)
endif()
+
+foreach(family_target ${family_targets})
+ target_sources(${family_target} PRIVATE $<TARGET_OBJECTS:chipdb-${family}>)
+endforeach()
diff --git a/ice40/resource/chipdb.rc b/ice40/resource/chipdb.rc
index 46459538..0b248d74 100644
--- a/ice40/resource/chipdb.rc
+++ b/ice40/resource/chipdb.rc
@@ -1,7 +1,7 @@
#include "resource.h"
-IDR_CHIPDB_384 BINARYFILE "..\chipdbs\chipdb-384.bin"
-IDR_CHIPDB_1K BINARYFILE "..\chipdbs\chipdb-1k.bin"
-IDR_CHIPDB_5K BINARYFILE "..\chipdbs\chipdb-5k.bin"
-IDR_CHIPDB_U4K BINARYFILE "..\chipdbs\chipdb-u4k.bin"
-IDR_CHIPDB_8K BINARYFILE "..\chipdbs\chipdb-8k.bin"
+IDR_CHIPDB_384 BINARYFILE "ice40/chipdb/chipdb-384.bin"
+IDR_CHIPDB_1K BINARYFILE "ice40/chipdb/chipdb-1k.bin"
+IDR_CHIPDB_5K BINARYFILE "ice40/chipdb/chipdb-5k.bin"
+IDR_CHIPDB_U4K BINARYFILE "ice40/chipdb/chipdb-u4k.bin"
+IDR_CHIPDB_8K BINARYFILE "ice40/chipdb/chipdb-8k.bin"
generated by cgit v1.2.3 (git 2.25.1) at 2025-04-16 03:16:37 +0000